Universal K20UNV - Kermit-20 Universal Symbols and Macros

	search monsym		; Wants things for NTINF%
	search macsym		; Needs FLD, MASK, Etc.
	search cmd		; Also cmd
	remark Can't do the .nobin; confuses COMPIL (I.E., the EXEC)
;	.directive .nobin	; Doesn't need a .REL file

; Moved symbols and macros here from main module as part of 194

	subttl Kermit program definitions

pdlsiz==^d200			; Stack size, be generous.
takel==^d20			;[78] TAKE command JFN stack size.

; N.B., Be careful about the aliases done here and Kermit's regular
;    register usage.  Also, be VERY aware that p5 aliases ac15,
;    which macsym uses as the frame pointer for Bliss subroutine calls
;    asubr's and transient variables.  Stack vars and block. context
;    are uneffected

define cmdacs <			;;Have to clean up cmd accumulator polution
if1 <	ifdef p1,<purge p1>	;;CMD should be compiled seperately
	ifdef p2,<purge p2>
	ifdef p3,<purge p3>
	ifdef p4,<purge p4>
	ifdef p5,<purge p5>
>;;if1
	p1==q5			;;p1 aliases q5 and state
	p2==p1+1		;;p2 alias rchr
	p3==p2+1		;;p3 alias schr
	p4==p3+1		;;p4 alias debug
	p5==p4+1		;;p5 alias FP!!!
ifndef cx,<cx==17>		;;Occasional control linkage
>;;cmdacs

; Don't let values confuse DDT (or me)
f==0				; AC definitions:  flag AC (not used),
t4==<t3==<t2==<t1==1>+1>+1>+1	;  temporary AC's,     (Contiguous)
q4==<q3==<q2==<q1==t4+1>+1>+1>+1 ; and preserved AC's. (Contiguous)
t5==q1				;[186] Alias a temporary for double arithmatic

state==q4+1			; State of the automaton.
q5==state			;[211] Can also CAREFULLY use
				;[211] q5 aliases state AND p1
	cmdacs			;;Clean up for our definitions
rchr==state+1			; Total file characters received.
schr==rchr+1			; Total file characters sent.
debug==schr+1			;[22] Debugging (0=none, 1=states, 2=packets)

SOH==^o001			; ASCII Start of header character.
XON==^o021			; XON is defined to be Control-Q (ASCII DC1).
MAXBUF==^d10240			; Packet buffer size [179]
MAXPKT==^d94			; Packet buffer size [179]
IOBUF==^d9216			; Communications i/o buffer [180] [216] (9K)
				;[216] Enough for 9,000 character packet
maxpkt=="~"-" "+2		; Maximum size of a packet.
dmxtry==5			; Default number of retries on a packet.
dimxtr==20			; Default number of retries send initiate.
drpsiz==^d80			; Default receive packet size.
dspsiz==^d80			; Default send packet size.
spmin==^d10			;[47] Minimum size packet we want to send.
spmax==^d9000			;[47] Maximum ...
dstim==^d<8*1000>   ;[212] ms	; Default send time out interval.
dstimf==8.0	    ;[212] fl	; Same value as floating seconds
drtim==^d<13*1000>  ;[212] ms	;[128] Default receive time out interval.
drtimf==13.0	    ;[212] fl	; Same value as floating seconds
dsrvtm==^d<30*1000> ;[212] ms	;[20] Def timout when awaiting server commands.
dsrvtf==30.0	    ;[212] fl	; Same value as floating seconds
drpaus==0	    ;[212] ms	;[36] Default pause before ACKing packets.
drpauf==0.0	    ;[212] fl	;[35] Default pause before ACKing packets.
dspaus==0	    ;[212] ms	;[36] Default pause before sending packets.
dspauf==0.0	    ;[212] fl	;[36] Default pause before sending packets.
dspad==^o0			; Default send padding char.
drpad==^d0			; Default receive padding char.
drpadn==^d0			; Default number of receive padding chars.
dspadn==^d0			; Default number of send padding chars.
dpadmx==^d1024			;[223] Maximum number of padding chars we'll do
dseol==.chcrt			; Default send EOL char.
dreol==.chcrt			; Default receive EOL char.
dsquot=="#"			; Default outbound control prefix.
drquot=="#"			; Default incoming control prefix.
dqbin=="&"			; Default 8th-bit prefix.
drept=="~"			; Default repeat count prefix.
ddelay==^d5000      ;[212] ms	; Default delay before the first packet, msecs.
ddelaf==5.0	    ;[212] fl	;[194] Same as floating seconds (must give character)
dxfull==0			;[18] Full duplex.
dxhalf==1			;[18] Half duplex.
defesc==34			; Default CONNECT escape character is ^\.
defits==-1			;[75] Handle ITS binary files by default.
defics==0			;[160] Default case search for INPUT commands.
defita==0			;[160] Default timeout action for INPUTs.
defito==^d<5*1000>  ;[212] ms	;[160] Default timeout interval for INPUTs.
defitf==5.0	    ;[212] fl	;[194] Same value as floating point (as character)
maxtim=^d<94*1000>  ;[212] ms	;[2] Maximum timeout interval to set, secs.
minlod=4.0			;[2] Minimum ldav to consider for timeout.
maxlod=50.0			;[2] Maximum ldav to consider for timeout.
	COMMENT "		;[277] Variable sized Blips now
blip=^d5			;[4] Every this many packets, print a blip.

"				;[277] 
dblip==^d5			;[277] We do, however, have default blips

	subttl Definitions for Macro table remediation

; All part of 203.  There are the beginnings of a macro editor, but
; for this release, development was stopped after the storage issues
; were fixed.
;
; The design of the macro editor is largely complete, but the
; implementation of SET commands that have third (and fourth) level
; selections is not.  Briefly, everything parses, but to split things
; up, you have to handle the guide words, which may not be
; straightforward.
;
; The code is currently off.  Define the symbol EDTMAC to cause it to
; be part of the executable.  And understand that you will have some
; coding to do.
;
;	EDTMAC==:1		; Assemble (incomplete) macro editor

define emacro (stuff) <		;;If have macro editor code
ifdef EDTMAC, <
'stuff
>>

define nmacro (stuff) <		;;If DON'T have macro editor code
ifndef EDTMAC, <
'stuff
>>

	subttl FATAL Assembly errors

; Fatal assembly error macro.  It would have been nice if MACRO had
; something like an .ERROR statement.  Like ...MASM...

define .fatal (message) <
 pass2
 printx ?'message
 end
>;;define .fatal

	SUBTTL Handy macros for address conversion

; Lifted from Extended Mode FTP Server rewrite


	REMARK Convert between 30 bit addresses and 21 bit page numbers

pgshft==:^D9			; Shift for page/address conversion

define pg2adr (r,a) <		;; 21 bit page number
ifb <r>,<.fatal No register specified>
ifnb <a>,<.fatal 'a can only cast values in registers>
ifg r-^o16,<.fatal register 'r is out of bounds>
	lsh r,pgshft		;; Convert page to address
>

define adr2pg (r,a) <		;; 30 bit address
ifb <r>,<.fatal No register specified>
ifnb <a>,<.fatal 'addr can only convert values in registers>
ifg r-^o16,<.fatal Register 'r is out of bounds>
	lsh r,-pgshft		;; Convert address to page
>

	REMARK Convert between 21 bit page numbers and 12 bit section numbers

secsft==:^D9			; Shift for section/page conversion

define sec2pg (r,a) <		;; 12 bit section number
ifb <r>,<.fatal No register specified>
ifnb <a>,<.fatal 'a Can only cast values in registers>
ifg r-^o16,<.fatal Register 'r is out of bounds>
	lsh r,secsft		;; Convert section to page
>

define pg2sec (r,a) <		;; 21 bit page number
ifb <r>,<.fatal No register specified>
ifnb <a>,<.fatal 'a Can only convert values in registers>
ifg r-^o16,<.fatal Register 'r is out of bounds>
	lsh r,-secsft		;; Convert page to section
>

	REMARK Convert between 30 bit addresses and 12 bit section numbers

define sc2adr (r,a) <		;; 12 bit sction number
ifb <r>,<.fatal No register specified>
ifnb <a>,<.fatal 'a Can only cast values in registers>
ifg r-^o16,<.fatal Register 'r is out of bounds>
	hrlz r,r		;; Convert section number to address
>

define adr2sc (r,a) <		;; 30 bit address
ifb <r>,<.fatal No register specified>
ifnb <a>,<.fatal 'a Can only convert values in registers>
ifg r-^o16,<.fatal Register 'r is out of bounds>
	hlrz r,r		;; Convert address to section number
>
	subttl Clean symbol artifacts up

define cleans(s) <		;;Clean up symbols we won't need
irp s,<				;;Do all this for each and every symbol
  ifdef s,<			;;Nothing to clean up if not defined
    .xcref s			;;Don't want symbol in cross reference
    .ifn s,macro,<		;;If not a macro, do some other clean up
	.noddt s		;;Don't need symbol in DDT
	suppress s		;;Don't want symbol in symbol table listing
>;;.ifn
if2  <	purge s  >		;;After second pass, don't need symbol
>;;ifdef
>;;irp
>;;cleans

	subttl .PSECT switching

; Cuts down on typing because we aggressively use .PSECT's
;
; N.B., Does not nest like ifskp./else./endif. do.

define chgsec(f,t) <		;;From and To .PSECT's
	.endps 'f		;;Get out of the From .PSECT
	.psect 't		;;Get into To .PSECT
    define retsec <		;;Define remote macro to put things back
	.endps 't		;;Done with To .PSECT
	.psect 'f		;;Get back into From .PSECT
>;;retsec
>;;chgsec


	subttl Parity Types (actually table offsets)

.parno==0			; None
.parsp==1			; Space, bit 8 is zero, always
.parmk==2			; Mark, bit 8 is one, always
.parev==3			; Even parity
.parod==4			; Odd parity

	subttl Various MACRO sizings

; The total macro table size is driven off the number of macros we can
; handle in the TBLUK% table and its associated string storage.  We
; make some assumptions here that may or may not actually be true.
; These are,
;
;   1)	A macro name (which is really 'only' a TBLUK% keyword) is
;	rarely going over 10 characters (or two PDP-10 words)  *AND*
;
;   2)	Its expansion is rarely over 90 characters (or 18 words).
;
; If the numbers turn out to be wrong, they are easily changed.
; The MACROS .PSECT is then sized from the lengths calculated here.
;
; However, the number of macros was simply picked by what would fit
; in seven pages of memory.

macmax==^d170		;[203]	;[77] Maximum number of macros.
mnblen==^d2*macmax	;[203] 	;[77] Macro name buffer length in words (10 chars)
mtblen==^d18*macmax	;[203] 	;[77] Macro text buffer length in words (90 chars)

macslp==0		;[203] 	; Initially no slop

define adslop (n) <	;;[203]	; Add n to slop
    macslp==macslp+n	;;[203] ; Accumulate the extra words of slop
    .xcref macslp	;;[203] ; Still don't need this
>;;adslop

	adslop(1)	;;[203]	; mactab TBLUK% header word
	adslop(1)	;;[203]	; mactbx end of mactab
	adslop(1)	;;[203]	; macbp
	adslop(1)	;;[203]	; ibmkey
	adslop(11)	;;[203]	; ibmmac (macro body) [octal]
	adslop(1)	;;[203]	; macx

mactmp==macslp+macmax+mnblen+mtblen ;[203] Minimum length in words
macpgs==<mactmp_-^D9>		;[203] Minimum number of pages
ifn <mactmp&777>,<macpgs==macpgs+1> ;[203] Round up if not on a page boundar
gcpgs==macpgs			;[203] Garbage collection is same size
emacro < edpgs==macpgs >	;[203] As is the macro editing area
maclen==macpgs*1000		;[203] Now have length in words

	cleans(<mactmp,macslp>)	;[203] Don't need temporary after second pass

defbrk==3			; Default number of breaks.
maxnul==100			; Maximum number of nulls.

maxnam==^d40			; Maximum characters in a system name
syslen==<<maxnam/5>+1>		; Number of words in name block

MXPKTW==<<MAXPKT/4>+1>		; Maximum packet size in words
strblw==1000			;[209] String buffer length in words
strblc==1000*5			;[209] Same value in ASCII characters
strbl8==1000*4			;[263] Same value when doing eight bit bytes

ifl <MXPKTW-mxpwlw>,<.fatal Maximum password will exceed packet length>

	remark Various maximums for files and directories

; Assume following would only include the ;t attribute
; device:<directory>name.type.generation;attributes

mxfilc==^d<6+1+1+39+1+39+1+39+1+6+1+1>	; Maximum Tops-20 file path in characters
mxfilw==<mxfilc/5>+1			; Same thing in words

dirmxc==^d<6+1+1+39+1+1>        ; Maximum Tops-20 directory characters (+ .chnul)
dirmxw==<<dirmxc/5>+1>          ; Same constant in words

mxpwlc==^d39			; Maximum size password Tops-20 will allow
mxpwlw==^d<<mxpwlc/5>+1>	; Maximum storage required

; These MUST match CMDSTG, which does not declare the symbols
; so that MACRO can use them to allocate static storage, sigh...

fdrmxc==<^d80*6>		; Foreign Directory Maximum size in characters
fdrmxw==<fdrmxc/5>+1		; Same size in words, plus slop

fpwmxc==fdrmxc			; Foreign maximum password size in characters
fpwmxw==fdrmxw			; Size size in words, plus slop

; Some characters that would be nice in MACSYM ...

.chdbq==42			; Double quote
.chsnq==47			; Single quote (or apostrophe)
.chlpa==50			; Left parenthesis
.chrpa==51			; Right parenthesis
.chlpt==74			; Left pointy bracket
.chrpt==76			; Right pointy bracket
.chupa==136			; Up arrow

	subttl Tops-20 Monitor Definitions and extensions

;[129] ARPA definitions (may not be in MONSYM)

ifndef STAT%,<opdef STAT% [JSYS 745]> ; So this will assemble
ifndef TCP%NT,<TCP%NT==40000000> ; without symbols from BBN TCP monitor.

;TELNET negotiation options if not running a PANDA monitor

iac==377			; arpanet telnet IAC
will==373			; telnet will <option>
wont==374			; telnet wont <option>
do==375				; telnet do <option>
dont==376			; telnet don't <option>
trnbin==0			; transmit binary

; PANDA monitor has these built in as an MTOPR%

ifdef  .morlt,<pandasw==1>	;[181] Assemble if we have monitor support
ifndef .morlt,<pandasw==0>	;[181]   Or not...

define panda <ifn pandasw , >	;[181]     and a handy abbreviation!

; DECnet definitions

;[182] Wouldn't it be REAL nice if these fields were defined in MONSYM?

ntflag==maskb(0,8)		;[182] Terminal flags
nttype==maskb(9,17)		;[182] Network type
ntline==maskb(18,35)		;[182] Line type
ntblen==<.nwnu1+2>		;[182] Minimum length

;[236] Another field that might have been defined ...

.SHARG==:0			;[236] Length of block to .MOSNH
.SHLEN==.SHESC+1		;[236] Length of block itself

;[186] Fields for a DECnet node which might have been defined ...

N%AREA==77B25			;[186] DECnet Area Number
N%NODE==1777B35			;[186] DECnet Node Number

;[186] Extended node verify (requires monitor edit T79)
;      Also, see .ndvfy MTOPR%

ifndef .ndvfx,<			; Not defined in this monsym?
.ndvfx==:23			; Verify Node Name, Extended
		remark		; More flags, see .ndvfy
		nd%num==:1b4	; Node number returned
		nd%scl==:1B5	; SCLINK secondary error being returned
	.ndnum==:2		; Area, node number (in addition to flags)
>

;[239] Define high precision time of day if old monsym doesn't have it

ifndef .hptod,<.hptod==:4>	;[239] 

; Mask for any wildcarded fields from GTJFN%/COMND%

gj%wld==gj%dev!gj%unt!gj%dir!gj%nam!gj%ext!gj%ver

; Define a few numeric operating system types.
;
; Be painfully aware that these are NOT the same as the OSTYPE field
; of the CONFIG message in DAPSYM!  Verified with HECnet experts.

	TOPS20==^D8
	TOPS10==^D9
				; Maximum length of a DECnet NRT object (?)
objlen==^d<6+1+1+39+1+39+1+39+1+7>

; Network Remote Terminal protocole types are in a 16 bit field.
; These have been reverse engineered from the configuration message as
; reported by the following HECnet hosts:
;
;	ROSSAK	RSTS/E
; 	MIM	RSX-11M
;	APOLLO	VMS
;	TOMMYT	TOPS-20
;	VENTI	TOPS-10
;
; and confirmed with some ex-Digital DECnet engineers.  None of the
; protocols are compatible with each other (naturally)

RSTNRT==1B35			; RSTS/E NRT
RSXNRT==1B34			; RSX NRT
VMSNRT==1B33			; VMS NRT
TOPNRT==1B32			; Tops-10/Tops-20 NRT (which Ultrix also supports)

.jiker==.jilno+1		;[220] Size of block gotten with GETJI%


	subttl KL PC flags (in right halfword in section zero)

klflgs==pc%ovf!pc%cy0!pc%cy1!pc%fov!pc%bis!pc%usr!pc%uio
klflgs==klflgs!pc%lip!pc%afi!pc%atn!pc%fuf!pc%fuf

	subttl Capability Mask

; Contains what we do not want to be running with.
;
; Internet (sc%ana) and DECnet capabilities are left alone, yet
; nothing currently checks these, including any known PANDA ACJ.
;
; N.B., We leave SC%WHL and SC%OPR alone to allow them to be managed
;	from the EXEC, but probably it is a bad idea to leave them on.

define badbit (b,w<badmsk>) <	;;Default the mask word
	w==w!b			;;Accumulate in mask
>;;nobits

	badmsk==0		;;Initialize mask

; Capabilities we NEVER want on (in order)

	badbit(sc%mmn)		;;There will be no mapping of the monitor!
	badbit(sc%sdv)		;;Nor any phonky special devices
	badbit(<1b7!1b8>)	;;Do not allow undefined bits
	badbit(sc%sup)		;;Don't dink the EXEC
	badbit(maskb(10,16))	;;Do not allow undefined bits
	badbit(sc%frz)		;;Don't freeze of failure, fail!
	badbit(sc%cnf)		;;No peeking at the monitor, either
	badbit(sc%mnt)		;;No diddling of the hardware
	badbit(sc%ipc)		;;Do not fill up the IPCF pool
	badbit(sc%enq)		;;Nor muck around with queue locks
	badbit(sc%nwz)		;;No net wizard magic
	badbit(sc%nas)		;;Nor absolute 'sockets'
	badbit(sc%sem)		;;Definately not a Galaxy operator!
ifdef sc%adm,<			;;If monitor has PANDA administrator
	badbit(sc%adm)		;;Shut that off, too
	badbit(maskb(29,34))	;;Do not allow undefined bits
>
ifndef sc%adm,<			;;If monitor does not have PANDA administrator
	badbit(maskb(29,35))	;;Do not allow undefined bits
>
	badbit(sc%mea)	;;[252]	;;Don't allow into mini-exec
	show. (badmsk)		;;Show value in listing

	subttl .PSECT management

; All part of 190

; N.B., Unfortunately, DEC never finished enhancing .PSECT's to allow
;    for relocation.  Thus, all lengths must be estimated, even if
;    known only to LINK (such as the PDV and the symbol table) and the
;    layout must be done by hand. 
;
;    While this allows LINK to catch possible overlap and for read-
;    only areas (which Tops-20 supports as a kind of superior form of
;    Tops-10's high segment), LINK didn't do it until version 7. 
;
;    The numbers below can be tweaked with the output of the /counters
;    switch and the .MAP file, both of which the .MIC file creates.
;
;    Be aware that the last 64 pages of section zero are reserved by
;    LINK for in-section use of DDT.  This is normally never done
;    anymore, XDDT being in section 37 and only page 777 of section
;    zero being used.  If you run out of space, try (in order),
;
;    1)	Shift the entire code segment down by changing BASORG.  It is
;	hundreds of pages away from the top of writable storage (the
;	.DATA .PSECT)
;
;    2)	Move the program text out of section zero and point to it with
;	one word global pointers.  This is a fairly easy change to
;	make and has already been done for the help text.  See $help2.
;
;    3)	Move the macro processing and tables out.  Somewhat more complex
;
;    4)	Move various code that is section agnostic into another section.

	remark			; Sizes of various psect's
	pdvlen==<^d1>*1000	; PDV doesn't take up much space, at all
	txtlen==<^d4>*1000	; Pages of section 0 ASCII text
	conlen==<^d14>*1000	; Pages of section 0 constants, tables and pointers

	gplen==^d512		; A guard page has 512 words
	maplen==^d512		; Only maps a single page at a time
	patlen==<^d2>*1000	; Pages for code patches (debugging only)
	devpgs==^d4		; Pages of storage for device timing 
	devlen==^d<512*devpgs>	; Same, as words
	ptypgs==^d1		; Single page read and write for PTY timing
	ptylen==^d<512*ptypgs>	; Same, as words
	nulpgs==devpgs-1	; Replication for NUL: timing
	nullen==^d<512*devpgs>	; But writing all of them
	wrtlen==<^d37>*1000	; Large amount of writable storage
	devorg==2000		; Start with timing pages
	nulpag==devorg_-^D9	; Associated page number
	macgp1==devorg+devlen	; Macro guard page 1 (before mapping window)
	maporg==macgp1+gplen	; Single page window for mapping files.
	macgp2==maporg+maplen	; Second gaurd page is after file mapping window
	macorg==macgp2+gplen	; Macro storage start after 2nd guard page
	macgp3==macorg+maclen	; Third guard page is after macro storage
	gcorg==macgp3+gplen	; Garbage collection is after 3rd guard page
	macgp4==gcorg+maclen	; Fourth guard page is after garbage collection
emacro <			;;Storage if Macro editing is completed
	medorg==macgp4+gplen	; Macro editing is after the fourth guard page
	macgp5==medorg+maclen	; Fifth guard page is after macro editing
	patorg==macgp5+gplen	; Some patch space out of the way
>
nmacro <
	patorg==macgp4+gplen	; Some patch space out of the way
>
	grdorg==patorg+patlen	; Guard page from executable
	datorg==grdorg+1000	; Give rest of 'low segment' to data storage

	remark associated useful page numbers

	mappag==maporg_-^d9	; File window page number
	macpag==macorg_-^d9	; Macro storage, first page
	gcpag==gcorg_-^d9	; Macro garbage collection, first page
emacro < medpg==medorg_-^d9 >	; Macro editing, first page
	grdpag==grdorg_-^d9	; Guard page number
	remark			; gcpag MUST come after macpag!!!

	remark			; Read-only areas, section zero
	basorg==572000		; Beginning location of write protected areas
	pdvorg==basorg		; Program Data Vector is first
	txtorg==pdvorg+pdvlen	; Section zero text are after the PDV
	conorg==txtorg+txtlen	; Section zero constants come before code
	codorg==conorg+conlen	; Code is in a very high 'high segment'

	extsec==1		; Extended section with help and extended text
	remark Discusting hack to make $help work right...
	hlporg==<extsec,,macorg+maclen>	; Don't alias the macro table!!!
	etxorg==<extsec,,300000> ;Extended text at page 300 (far away)
	symorg==<extsec,,400000> ;Symbols are at page 400
	ecnorg==<extsec,,conorg> ;Extended Constants mimics section zero
	ecdorg==<extsec,,basorg> ;Extended code mimics section zero insection
	edaorg==<extsec,,650000> ;Extended data section

	smpsec==3		;[263] Section for mapping a whole file
	smporg==<smpsec,,00>	;[263] Starts at page zero, address zero
	smppag==smporg_-^d9	;[263] Turn the address into a page

	remark			; Don't need below because moved to extended section
;	hlplen==<^d25>*1000	; Pages of ASCII help text
;	symlen==<^d21>*1000	; Pages of symbols
;	ecdlen==<^d1>*1000	; Pages of extended code


	SUBTTL Symbol table definitions (from PROLOG and DDT)

; N.B., .STDEC and .STSIZ were not defined by DEC... [should have been]
;       Definitions of SY%TYP and SY%LEN in PROLOG contradict what is
;       in LINK.DOC and DDT.MAC!!!
;
;	These are necessary because of older EXEC's which do not look
;	at the program data vector for symbols.  Kermit patches .JBSYM
;	to have the correct value on start up, which it must do
;	because we link without Tops-10 symbols (/NOINITIAL).  We also
;	run with PA1050 disallowed to remain pure of heart.

	.UNDFD==0		; Undefined symbol table type
	.R50D==1		; Radix-50 defined symbol table
	.R50U==2		; Radix-50 undefined symbol table
	.STLEN==0		; Offset of length word in subtable
	.STDAT==0		;   "    " data type "  "     "
	.STPTR==1		;   "    " address   "  "     "
	.STDEC==2		; DEC's foolish reserved zero word
	.STSIZ==3		; Size of subtable
	ST%TYP==77B5		; Type field mask
	ST%LEN==^-ST%TYP	; Length field mask

	subttl Terminal save block bit fields

ts%bit==0			; Terminal save bit
	.xcref ts%bit		; Don't need in cross reference
	suppress ts%bit		; Don't need in symbol table listing

define tsflag (name,bit<ts%bit>) < 
	ifle <^d35-bit>,<.fatal Terminal save flags word exceeded>
	name==1b<bit>		;;Assign the bit number to the flag
	bit==bit+1		;;Bump to next bit
>

	tsflag(ts%err)		;;If any errors encountered during save
	tsflag(ts%ctm)		;;Calling argument was controlling terminal
	tsflag(ts%pro)		;;Calling argument was primary output
	tsflag(ts%frk)		;;Calling argument was a fork handle
	tsflag(ts%jfn)		;;Calling argument was a JFN
	tsflag(ts%dev)		;;Calling argument was device designator
	tsflag(ts%pip)		;;Calling argument was a pipe
	tsflag(ts%efh)		;;Explicit fork handle specified
	tsflag(ts%ctc)		;;Fork had ^C capability
	tsflag(ts%lgw)		;;Large terminal width
	tsflag(ts%lgl)		;;Large terminal length

	show. ts%bit		;;Show used bit in listing

	cleans(<tsflag,ts%bit>)	;;Won't use symbol anywhere else


	subttl Terminal save block offsets

	phase 0			; Addressing starts from beginning of block

$tsflg:	block 1			; Flags for ttysav
$tsarg:	block 1			; Whatever handle ttysav was called with
$tserr:	block 1			; Last error encountered
$gpjfn:	block 2			; Primary JFN's and any error
$dvchr:	block 4			; Device characteristics and any error
$ctcoc:	block 3			; Controlling terminal COC's and error
$ctmod:	block 2			; Controlling terminal mode word and error
$morlw:	block 2			; Controlling line width
$morll:	block 2			; Controlling line length
$mornt:	block 2			; Receive system blat
$morxo:	block 2			; Pause end of page
$mopcr:	block 2			; Read terminal pause and unpause
$mortf:	block 2			; Read other kinds of blat
panda <				; PANDA TVT bits
$morlt:	block 2			; Read TVT bits
>
$morbm:	block 6			; 128 character break mask
$tif:	block 1    ; DO NOT	; Terminal Interrupt Fork (actually scope)
$tiw:	block 3    ; REORDER	; Terminal Interrupt Word and RTIW% result

$tslen==<.+1>			; Length of structure
	dephase			; Get back to regular relocation

	subttl Terminal mode word mask

;[151] Set up TTY for linking, and open any logging file.
;[129] Add TT%DUM
;[194] Moved here and documented better (or more profusely...)

$modof==0			;[194] Bits we want off

define ttmode (bit) <		;;Macro to accumulate bit in mode word
	$modof==$modof!bit	;;OR into the mode word
	.xcref $modof,bit	;;Don't fill up the cross reference...
>
	ttmode(tt%eco)		;;Shutting off echoing
	ttmode(tt%dam)		;;binary data mode (whacks field flags)
	ttmode(tt%dum)		;;Force full duplex (whacks field flags)
	ttmode(tt%lic)		;;Do not raise lower case on input
	ttmode(tt%wkf)		;;Don't wakeup on formating control chars
	ttmode(tt%wkn)		;;Don't wakeup on non-formatting control chars
	ttmode(tt%wkp)		;;Don't wakeup on punctuation
	ttmode(tt%wka)		;;Don't wakeup on alphanumerics
	ttmode(tt%wid)		;;Infinite width (0)
	ttmode(tt%len)		;;Infinite length (0)
	ttmode(tt%uoc)		;;Do not indicate upper case

	SHOW. $modof

	cleans (<ttmode>)	;;Don't need working macro

	subttl Various MOVST codes

;[209] Begin code insertion

IF1 <					; MACRO know about this?
	IFDEF MOVST ,<PURGE MOVST>	; Toss, since no output to DDT!
	IFDEF MOVSLJ,<PURGE MOVSLJ>	; Toss, since no output to DDT!
>

OPDEF MOVST  [XWD 015000,0]		; Define MOVST for DDT, too
OPDEF MOVSLJ [XWD 016000,0]		; Define MOVSLJ for DDT, too

S==1B0					; Significance Bit
N==1B1					; Set if not NUL
M==1B2					; Mark
OPCODE==7B2				; Per character translation opcode
EOSCOD==(FLD(1,OPCODE))			; Just terminate
STRCOD==(FLD(7,OPCODE))			; Start translating, setting S, N and M
TRMCOD==(FLD(5,OPCODE))			; Terminate and set 'N' 

;[209] End code insertion

	subttl anstkv -- anonymous stkvar.

; Like a stack variable except that a name isn't defined.  An
; accumulator is given to hold the resolved address of the base of the
; block of storage carved off the stack.  Otherwise, works like
; regular co-routine based stkvar, see MACSYM.
;
; Unlike a regular stkvar, anonymous stack variables are bound to the
; address which is resolved in the indicated accumulator.  Therefore,
; intermediate stack operations will not cause a misreference and the
; pointer may be passed to a called routine.
;
; N.B., Be aware of the following:
;
;   1)	An anonymous stack variable is ONLY valid for the
;	duration of the routine which invokes it.  It can
;	not be passed 'up' (or back) to a caller because
;	the return will deallocate the stack space.
;
;  2)	adjsp is used, which can cause a stack overflow!

define anstkv (ac,len) <
	jsp .a16,.xstks		;;Call MACSYM internal co-routine for allocation
	 exp len		;;Amount of stack space to reserve
	xmovei ac, -<len+1>(p)	;;Calculate base of block (skip size and return)
>
	subttl macro to print a message from extended text .psect

.px7==<.P07!<.lhalf&etxorg>>	; Pointer to extended text

; Like TMSG, but gets the text out of the code segment.  Makes for
; easier stepping through the code space; instructions are really
; instructions--not ASCII looking like baffling instructions.
; Better cache characteristics, too

define txmsg (t,%t,%et) <	;;Prints message from text .psect
	move t1, %t		;;Load the pointer
	PSOUT%			;;Do the blat
	 erjmpr .+1		;; Ignore error, leave artifact
	chgsec(code,const)	;;Read only pointers are constants
%t:	.px7!%et		;;Point to text in extended section
	retsec			;;Close out constants
	chgsec(code,etext)	;;Open the extended text .psect
%et:	asciz \'t\		;;Emit the text of the message
	retsec			;;Reopen the code .PSECT
	cleans(<%t,%et>)	;;Don't need generated symbols taking up space
>;;txmsg

	subttl macro to parse for a noise word from extended text .psect

; Different from CMD.MAC's NOISE because text is in extended section

define guide (n,%n,%en) <	;;Guides from text .psect
	move cx, %n		;;Load the pointer to the noise
	call noirtn		;;Blat some guidance
	chgsec(code,const)	;;Read only pointers go in constants
%n:	.px7!%en		;;Drop in an extended pointer
	retsec			;;Close out constants .psect
	chgsec(code,etext)	;;Open the extended text .psect
%en:	asciz \'n\		;;Emit the noise words
	retsec
	cleans (<%n,%en>)	;;Keep symbols off of listings and storage
>;;guide

	remark Macros and COMND% tables and FDB's

;[217] Helper to define various tokens

;N.B., have to use literals here or flddb. will choke.  Maybe rewrite
;    this to special case .cmtok, like fldtk.?

define token (c) <		;;Define token
	<point 7 [asciz "'c"]>	;;All these literals, yuck...
>;;token 

;[217] Helper macro to clean up lots of symbols when using tokens

define tokcln (pr,ps,n) <	;;Clean up massive token usage
    irpc n,<			;;Go through all the numeric suffix's
	'ps 'pr'n		;;pseudo-op and its symbol
>;;irpc				;;End of argument expansion
>;;tokcln

	subttl ERMSG%

;  Type an error message on local terminal and save a pointer to the
;  error string which can be used when querying most recent error.
;
; Rewritten for 187 and 194 (MCRNEC issues)
;
;  Renamed to not clash with the MACSYM macro of the same name.

define ermsg% (msg,label,%ptr,%txt,%skp) <
	skipa t1,%ptr		;;Makes skipable
	 jrst %skp		;;If skipped, go past the ESOUT%
	movem t1, errptr	;;Save for interesting parties
	ESOUT%			;;Type a compliant error message
ifnb <label>,<	jrst label >	;;When we finish, may get told to go elsewhere
%skp:	remark			;;Create the skip address
	chgsec(code,const)	;;[202] Pointers to extended text go in constants
%ptr:	.px7!%txt		;;[202] ASCII OWGP to text
	retsec			;;[202] Close out constants .PSECT
	chgsec(code,etext)	;;[202] Open the extended text .PSECT
%txt:	asciz \KERMIT-20: 'msg
\				;;[202] Emit text in extended text .PSECT
	retsec			;;[202] Reopen the code .PSECT
	cleans(<%ptr,%txt,%skp>) ;;[202] Clean up symbol usage
>;;ermsg%

	subttl KERMSG

;  Like ERMSG, but also send the message to the other KERMIT
;  in an error packet, which cancels the current transfer.
;
; Rewritten for [194]

define kermsg (msg,label,%cnt,%txt,%skp) <
	%cnt==^d11		;;Account for header
	irpc msg, <%cnt=%cnt+1>	;;Add in the characters in the text

	skipa			;;Make skipable
	 jrst %skp		;;Skipped
	jsp t1,%kerms		;;Hits the routine
	    %cnt		;;Count of characters
	    .px7!%txt		;;[202] ASCII OWGP to extended text
ifb <label>, <	jrst %skp  >	;;Standard return is to skip the arguments
ifnb <label>,<	jrst label>	;;Unless we get told to go elsewhere
%skp:	remark			;;Create skip address
	chgsec(code,etext)	;;[202] Open the extended text .PSECT
%txt:	asciz/'msg/		;;[202] Emit text in extended text .PSECT
	retsec			;;[202] Reopen the code .PSECT
	cleans(<%cnt,%skp,%txt>) ;;[202] Clean out of storage and listings
>;;kermsg

	subttl %JSERR

; Invoked by ERJMP after a JSYS call.  Prints the given message, if
; any, then the JSYS error message, and then jumps to the address
; given or else halts (continuably) if no jump address given.
;
;[163] Make it include the address of the failing JSYS at end of message.
;
; Rewritten for 194 because of MCRNEC errors (caused by macro expansion)

define %jserr (msg, label, %txt, %nxt, %skp) <
	erjmpr %nxt		;;Hit error handler, AC1 has error code
	 jrst %skp		;;Make skipable
%nxt:	jsp t1, %%jser		;;Call internal handler
ifb  <msg>,<  0  >		;;If no text, then pass nothing in
ifnb <msg>,< .px7!%txt >	;;[202] ASCII OWGP to text
ifb <label>, <	jrst %skp  >	;;Standard return is to skip the arguments
ifnb <label>,<	jrst label>	;;Unless we get told to go elsewhere
ifnb <msg>,<			;;[202] Only necessary if we have text
	chgsec(code,etext)	;;[202] Open the extended text .PSECT
%txt:	asciz \'msg\		;;[202] Emit text in extended text .PSECT
	retsec			;;[202] Reopen the code .PSECT
>;;ifnb msg			;;[202] End of non-blank message conditional
%skp:	remark			;;Create skip address
	cleans(<%txt,%nxt,%skp>) ;;[202] Clean up generated symbols
>;;%jserr

	subttl %ermsg -- Error message with last JSYS error

; Kind of like ermsg%, but more like %jserr (except no erjmpr)
;
; Rewritten for 194 because of MCRNEC errors (caused by macro expansion)

define %ermsg (msg, label, %txt, %skp) <
	skipa			;;Make skippable
	 jrst %skp		;;Skipped
	jsp t1, %%jser		;;Call internal handler
ifb  <msg>,<  0  >		;;If no text, then pass nothing in
ifnb <msg>,< .px7!%txt >	;;[202] ASCII OWGP to text
ifb <label>, <	jrst %skp  >	;;Standard return is to skip the arguments
ifnb <label>,<	jrst label>	;;Unless we get told to go elsewhere
%skp:	remark			;;Create skip symbol
ifnb <msg>,<			;;[202] Only necessary if we have text
	chgsec(code,etext)	;;[202] Open the extended text .PSECT
%txt:	asciz/'msg/		;;[202] Emit text in text .PSECT
	retsec			;;[202] Reopen the code .PSECT
>;;ifnb msg			;;[202] End of non-blank message conditional
	cleans(<%txt,%skp>)	;;[202] Clean up generated symbols
>;;%ermsg

	subttl %JSKER

; Like %JSERR, but also sends message to other KERMIT in an error
; packet, as KERMSG does.
;
; Rewritten for 194 because of MCRNEC errors (caused by macro expansion)

define %jsker (msg, label, %txt, %nxt, %skp) <
	erjmps %nxt		;;Hit the error handler, suppressing error
	 jrst %skp		;;Make skipable
%nxt:	jsp t1, %%krms		;;Call the error handler
ifb  <msg>,<  0  >		;;If no text, then pass nothing in
ifnb <msg>,< .px7!%txt >	;;[202] ASCII OWGP to text
ifb <label>, <	jrst %skp  >	;;Standard return is to skip the arguments
ifnb <label>,<	jrst label>	;;Unless we get told to go elsewhere
%skp:	remark			;;Create skip address
ifnb <msg>,<			;;[202] Only necessary if we have text
	chgsec(code,etext)	;;[202] Open the extended text .PSECT
%txt:	asciz/'msg/		;;[202] Emit text in extended text .PSECT
	retsec			;;[202] Reopen the code .PSECT
>;;ifnb msg			;;[202] End of non-blank message conditional
	cleans(<%txt,%nxt,%skp>) ;;[202] Clean up generated symbols
>;;%jsker

	subttl %ERKER

;Like above, but can simply be invoked anywhere (no erjmp)

define %erker (msg, label, %txt, %nxt, %skp) <
	jrst %nxt		;;Hit the error handler, suppressing error
	 jrst %skp		;;Make skipable
%nxt:	jsp t1, %%krms		;;Call the error handler
ifb  <msg>,<  0  >		;;If no text, then pass nothing in
ifnb <msg>,< .px7!%txt >	;;[202] ASCII OWGP to text
ifb <label>, <	jrst %skp  >	;;Standard return is to skip the arguments
ifnb <label>,<	jrst label>	;;Unless we get told to go elsewhere
%skp:	remark			;;Create the skip symbol
ifnb <msg>,<			;;[202] Only necessary if we have text
	chgsec(code,etext)	;;[202] Open the extended text .PSECT
%txt:	asciz/'msg/		;;[202] Emit text in extended text .PSECT
	retsec			;;[202] Reopen the code .PSECT
>;;ifnb msg			;;[202] End of non-blank message conditional
	cleans(<%txt,%nxt,%skp>) ;;[202] Clean up generated symbols
>;;%erker

	subttl Useful block structured MACROs (lifted from SETNODE rewrite)

; These ought to have gone in MACSYM...
;
; Enhance these to take an arbitrary argument to load a register
;
; When being used, can these generated symbols be purged?

DEFINE IFMX. (X)<			;;Define each macro
  IRP X,<				;;Go through each type
  DEFINE IFM'X'. (M,%TG1,%TG2)<		;;execute IF Memory is X
	SKIP'X M			;;Skip if less then zero
	 JRST %TG1			;;Go to false, since zero
	..SVDF				;;SAVE OUTER BLOCK
   DEFINE ..TAGF (INST,PCT)<
	INST %TG1''PCT>			;;DEFINE FALSE TAG
   IFDEF %TG1,<				;;Is FALSE tag in use?
	.XCREF %TG1			;;Get out of my cross reference!!
	.NODDT %TG1			;;Get out of my DDT session!!
	SUPPRESS %TG1			;;Get out of my symbol table listing!!
>;;%TG1					;;End if FALSE (ELSE,ANSKP,ETC.)
   DEFINE ..TAGE (INST,PCT)<
	INST %TG2''PCT>			;;DEFINE END TAG
   IFDEF %TG2,<				;;Is TRUE (ENDIF.) tag in use?
	.XCREF %TG2			;;Get out of my cross reference!!
	.NODDT %TG2			;;Get out of my debugging session!!
	SUPPRESS %TG2			;;Get out of my symbol table listing!!
>;;%TG2
>;;IFMX.
>;;IRP
>;;IFMX.

; Generate useful forms of SKIP:  IFML., IFME., IFMLE., IFMGE., IFMN., IFMG.

	remark We don't need to see all the expansion blat
	xlist
	  IFMX. (<L,E,LE,GE,N,G>)
	list

; Does not generate SKIP or SKIPA

	subttl Misc macros

; Builds a counted message to send via DECnet interrupt

define bldmsg (m,%l) <		;;Build interrupt message
	%l=0			;;Initially no length
	irpc m,<%l=%l+1>	;;Count the characters
	ifg <%l-^d16>,<PRINTX NRT Interrupt message too long>
	nrtlen==%l		;;Record the length
	asciz \'m'\		;;Drop the string
	cleans(<%l>)		;;Clean up symbol table usage
>;;bldmsg


; NUMOUT - Type a number in the desired base (decimal by default), free format.
;
; N.B., reduced in size to handle MCRNEC, so:
;
;  1)	NOT skippable
;  2)	Trashes t1, t2 and t3

define numout(num,base<^d10>) <
	movei t1, .priou
	move t2, num
	movei t3, base
	NOUT%
	 erjmps .+1
>;;numout

; OUTCHR - Type a character at the terminal without disturbing any registers.
;
; N.B., reduced in size to handle MCRNEC, so NOT skippable
;
; NOTE: EXCH will BREAK in a literal that is in a write protected .PSECT!!

define OUTCHR(char) <
	push p, t1
	move t1, char
	PBOUT
	 erjmpr .+1
	pop p, t1
>;;OUTCHR

	subttl Write time-stamped file message to the transaction log file [126]

; Macro arguments are a message string and the address of a JFN
; of the filename we want in the log, e.g.
;
;	wtlog (<Sending >,filjfn)
;
; N.B., reduced in size to handle MCRNEC, so NOT skippable!!

define wtlog(m,f,%c,%em) <
	%c=0			;;Count of characters is initially zero
	irpc m,<%c=%c+1>	;;Count the characters in the message
	jsp t1,%wtlog		;;Call the macro helper
	.px7!%em		;;OWGP to Extended Text Section
	-<%c>			;;Suitable for dmove to a counted SOUT%
ifb  <f>, <0>			;;If no file, then don't do anything
ifnb <f>, <f>			;;Otherwise, load the address of the JFN
	remark			;;Macro helper returns here
	chgsec(code,etext)	;;Text is in extended text section
%em:	asciz/'m/		;;So emit it here
	retsec			;;Back to generating code
	cleans(<%c,%em>)	;;Clean up generated symbols
>;;wtlog

; Time structure for fine-grained time of day timing.  This is
; problematic in standard Tops-20 because setting time of day
; does not record the system uptime when the time of day was set.

	phase 0			; Define the date and time timing structure
.dattd:! block 1		; Current Time of Day (TOD) in unsigned ticks
.dattl:! block 2		; Current Time of Day (TOD) as signed double
.dattr:! block 2		; Current Time of Day (TOD) millisecond remainder
.dateh:! block 2		; Elapsed Time of Day (TOD), HP tick base
.datdk:! block 2		; Remainder DK10 ticks if doing elapsed
.datem:! block 2		; Elapsed Time of Day (TOD), millisecond base
.datmr:! block 2		; Remainder milliseconds if doing elapsed
.datms:! block 2		; Uptime in milliseconds
.datus:! block 2		; Elapsed HPTIM% (tens of microseconds)
dtilen==.-.dattd		; Date and time structure length
	dephase			; Done; back to regular storage allocation

	subttl Various CMD helpers

;[248] Unfortunately CMD will only let you define the storage, but you
;    can't use any of the constants for useful things like defining
;    blocks of storage.  These have to be the same length as CMDSTG!!

define CMDUNV <			;;Do NOT use in same module as CMDSTG!!
CMDBLN==<^D80*6>/5+1		;;Room for six line command
extern CMDBUF			;;Reference to command buffer
extern CMDACS			;;Saved AC's from beginning of command line
ATMBLN==CMDBLN			;;Atom buffer buffer length
extern ATMBUF			;;Holds last parsed field
extern SBK			;;COMND% JSYS state block
CJFNLN==20			;;Length COMND%'s GTJFN% block
extern CJFNBK			;;GTJFN% block for COMND% JSYS
extern REPARA			;;Reparse address for COMND%
extern CMDFRM			;;Marks bottom of stack
CMDPLN==200			;;Amount of stack we can save
extern CMDPDL			;;Room to save stack (to restore on a reparse)
>;;CMDUNV

;[248] End MACRO insertion

; %TABLE - Beginning of COMND/TBLUK keyword table.
;
; Rewritten to minimize symbol table usage and respect .psects
;
; N.B, *MUST* change the .psect FIRST before declaring the label or
;    else the label will be in CODE whereas the actual table will be
;    in CONST...
;
; Also, can *NOT* use chgsec because chgsec does not currently nest.

define %table (l,g,%s) <	;;Has one generated symbol for start of table
	.endps code		;;Table does not go in code .psect
	.psect const		;; it goes into the constants .psect
ifb  <g>,<l':>			;;If blank, then module local symbol
ifnb <g>,<l'::>			;;If not blank, then global
	%s=l			;;Plant start of table (no DDT OUTPUT)
	exp 0			;;  and leave a hole for %tbend to fill

	define %tbend (%e,%h) <	;;N.B., defined INSIDE of %table!!!!
	%e=.			;;Get address of ending entry in table
	%h=%e-1-%s		;;Calculate number of entries
	reloc %s		;;Move back to start of table
	xwd %h, %h		;;Emit table header (# of entries,, maximum)
	reloc %e		;;Finally, get back to where we were
	.endps const		;;Done generating constant data
	.psectf code		;;Back to generating code
	cleans(<%s,%e,%h>)	;;Clean up generated symbols
> ;;End of %tbend
> ;;End of %table

	subttl %KEY - COMND or TBLUK keyword definition
;
; This macro takes three arguments: an (alphanumerics only!) keyword, the
; data to be associated with the keyword, and an (optional) flag value.  It
; creates either a flagless keyword (the normal case), or, if any flags are
; given, a keyword with flags in the first word and CM%FW set.  Thus,
; the result is a TBLUK table entry, suitable for use by the .CMKEY COMND
; JSYS function.  Note that all %KEY words in a table must be bracketed
; by %TABLE and %TBEND macros (see above).
;
; As part of [194] to reduce macro size, split into four seperate macros.
; somewhat less nifty to use, but reduces MACRO 'core' usage.  Macro names
; are 'unhappy'.  Better mnemonic?
;
; Don't use next two with literals!!
;
; N.B., All assume we are in const .psect
;
; To do, double indirection shouldn't leave addresses in TEXT.
;    However, if we switch back to CONST, then they will go into
;    the keyword table.  Define remote macro?

define %key2 (n, d, %a) <
	xwd %a, 'd		;;Left half is address of keyword
	chgsec(const,text)	;;Gets the string into the text psect
%a:	asciz \'n\		;;Emit the string (section zero)
	retsec 			;;Back to constants
	cleans(<%a>)		;;Clean up generated symbol
>;;End of %key2

define %key3 (n, d1, d2, %a, %d) <
	xwd %a, %d		;;Left half is address of keyword
	chgsec(const,text)	;;Gets the string into the text psect
%a:	asciz \'n\		;;Emit the string
	remark 			;;Double indirection can't go in keyword table
%d:	xwd 'd1, 'd2		;;Evalate and bind data
	retsec			;;Back to constants
	cleans(<%a,%d>)		;;Clean up generated symbols
>;;End of %key3

; Use for flags instead of literals!!

define %keyf3 (n, d, f, %a) <
	xwd %a, 'd		;;Left half is address of keyword
	chgsec(const,text)	;;Gets the string into the text psect
%a:	<'f>!cm%fw		;;Emit the flags with a flag word
	asciz \'n\		;;Emit the string
	retsec			;;Back to constants
	cleans(<%a>)		;;Clean up generated symbol
>;;End of %keyf3

define %keyf4 (n, d1, d2, f, %a, %d) <
	xwd %a, %d		;;Left half is address of keyword
	chgsec(const,text)	;;Gets the string into the text psect
%a:	<'f>!cm%fw		;;Emit the flags with a flag word
	asciz \'n\		;;Emit the string
	remark 			;;Double indirection can't go in keyword table
%d:	xwd 'd1, 'd2		;;Evalate and bind data
	retsec			;;Back to constants
	cleans(<%a,%d>)		;;Clean up generated symbols
>;;End of %keyf4

	subttl Construct OWGP to ASCII text, double word load

define dxtext (a,t,%c,%t,%et) <
	%c=0			;;Initialize character count (no output to DDT)
	irpc t,<%c=%c+1>	;;Count the characters in the ASCII text
	dmove a, %t		;;Double load pointer and count
	chgsec(code,const)	;;Open the constants .psect (in section zero)
%t:	.px7!%et		;;Point to text in extended section
	-<%c>			;;Counted SOUT% wants a negative number
	retsec			;;Close out section zero constants.psect
	chgsec(code,etext)	;;Open the extend text .psect
%et:	asciz \'t\		;;Emit the text of the message
	retsec			;;Back to regular code
	cleans(<%c,%t,%et>)	;;Clean up generated symbols
>;;End of dxtext

	subttl Construct OWGP to ASCII text, single word load

define sxtext (a,t,%t,%et) <
	move a, %t		;;Double load pointer and count
	chgsec(code,const)	;;Open the constants .psect (in section zero)
%t:	.px7!%et		;;Point to text in extended section
	retsec			;;Close out section zero constants .psect
	chgsec(code,etext)	;;Open the extend text .psect
%et:	asciz \'t\		;;Emit the text of the message
	retsec			;;Back to regular code
	cleans(<%t,%et>)	;;Clean up generated symbols
>;;End of sxtext

	subttl Construct OWGP to ASCII text, just drop the pointer

define eascii (t,%et) <		;;For use in code psect
	.px7!%et		;;Point to text in extended section
	chgsec(code,etext)	;;Open the extend text .psect
%et:	asciz \'t\		;;Emit the text of the message
	retsec			;;Back to regular code
	cleans(<%et>)		;;Clean up generated symbol
>;;eascii

;N.B., Can't use chgsec here because it doesn't nest

define cascii (t,%et) <		;;For use in const psect
	.px7!%et		;;Point to text in extended section
	.endps const		;;Close out the const psecy
	.psect etext		;;Open the extend text .psect
%et:	asciz \'t\		;;Emit the text of the message
	.endps etext		;;Close out the extended text
	.psect const		;;Back to const
	cleans(<%et>)		;;Clean up generated symbol
>;;eascii

	subttl Misc printing

; Like macsym's tmsg, but uses ESOUT% for errors.
;
; Think stderr, if you happen to be very young.

define emsg (t,%t,%et) <
	move t1, %t		;;Load Tops-20 pointer to string
	ESOUT%			;;Blat at the user
	chgsec(code,const)	;;Open the constants .psect (in section zero)
%t:	.px7!%et		;;Point to text in extended section
	retsec			;;Close out section zero constants .psect
	chgsec(code,etext)	;;Open the extend text .psect
%et:	asciz \'t\		;;Emit the text of the message with no CRLF
	retsec			;;Back to regular code
	cleans(<%t,%et>)	;;Clean up generated symbols
>;;End of emsg


; Following two are used to build text for REMOTE requests

define smsg (t,%c,%t,%et) <
	%c=0			;;Initialize character count (no output to DDT)
	irpc t,<%c=%c+1>	;;Count the characters in the ASCII text
	dmove t2, %t		;;Double load pointer and count
	call %%smsg		;;Go do something with it
	chgsec(code,const)	;;Open the constants .psect (in section zero)
%t:	.px7!%et		;;Point to text in extended section
	-<%c>			;;Counted SOUT% wants a negative number
	retsec			;;Close out section zero constants .psect
	chgsec(code,etext)	;;Open the extend text .psect
%et:	asciz \'t\		;;Emit the text of the message
	retsec			;;Back to regular code
	cleans(<%c,%t,%et>)	;;Clean up generated symbols
>;;smsg


; N.B., reduced in size to handle MCRNEC, so:
;
;  1)	NOT skippable
;  2)	Trashes t2 and t3
;  3)	Don't call inside a literal as the erjmp will go to the wrong place

define srvnum (num,base<^d10>) <
	move t2, num
	movei t3, base
	NOUT%
	 erjmps .+1
>;;srvum			;;[189] 

	end

; Local Modes:
; Mode:MACRO
; Comment Column:32
; Comment Start:;[277] 
; Comment Begin:;[277] 
; Auto Fill Mode: 0
; End: